Private IP support and test case

examples/mysql-private-ip/README.md

@@ -0,0 +1,18 @@
+# MySQL Cloud SQL Private IP Example
+
+This folder contains an example of how to use the [MySQL module](/modules/mysql) to create a [Google Cloud SQL](https://cloud.google.com/sql/) 
+[MySQL](https://cloud.google.com/sql/docs/mysql/) database instance with a private IP. 
+
+## How do you run this example?
+
+To run this example, you need to:
+
+1. Install [Terraform](https://www.terraform.io/).
+1. Open up `vars.tf` and set secrets at the top of the file as environment variables and fill in any other variables in
+   the file that don't have defaults. 
+1. `terraform init`.
+1. `terraform plan`.
+1. If the plan looks good, run `terraform apply`.
+
+When the templates are applied, Terraform will output the IP address of the instance 
+and the instance path for [connecting using the Cloud SQL Proxy](https://cloud.google.com/sql/docs/mysql/connect-admin-proxy). 

examples/mysql-private-ip/main.tf

@@ -0,0 +1,89 @@
+provider "google-beta" {
+  region  = "${var.region}"
+  project = "${var.project}"
+}
+
+# Use Terraform 0.10.x so that we can take advantage of Terraform GCP functionality as a separate provider via
+# https://github.com/terraform-providers/terraform-provider-google
+terraform {
+  required_version = ">= 0.10.3"
+}
+
+resource "random_id" "name" {
+  byte_length = 2
+}
+
+locals {
+  # If name_override is specified, use that - otherwise use the name_prefix with a random string
+  instance_name        = "${length(var.name_override) == 0 ? format("%s-%s", var.name_prefix, random_id.name.hex) : var.name_override}"
+  private_network_name = "private-network-${random_id.name.hex}"
+  private_ip_name      = "private-ip-${random_id.name.hex}"
+}
+
+resource "google_compute_network" "private_network" {
+  provider = "google-beta"
+  name     = "${local.private_network_name}"
+}
+
+resource "google_compute_global_address" "private_ip_address" {
+  provider      = "google-beta"
+  name          = "${local.private_ip_name}"
+  purpose       = "VPC_PEERING"
+  address_type  = "INTERNAL"
+  prefix_length = 16
+  network       = "${google_compute_network.private_network.self_link}"
+}
+
+resource "google_service_networking_connection" "private_vpc_connection" {
+  provider                = "google-beta"
+  network                 = "${google_compute_network.private_network.self_link}"
+  service                 = "servicenetworking.googleapis.com"
+  reserved_peering_ranges = ["${google_compute_global_address.private_ip_address.name}"]
+}
+
+module "mysql" {
+  # When using these modules in your own templates, you will need to use a Git URL with a ref attribute that pins you
+  # to a specific version of the modules, such as the following example:
+  # source = "git::git@github.com:gruntwork-io/terraform-google-sql.git//modules/mysql?ref=v0.1.0"
+  source = "../../modules/mysql"
+
+  project = "${var.project}"
+  region  = "${var.region}"
+  name    = "${local.instance_name}"
+  db_name = "${var.db_name}"
+
+  engine       = "${var.mysql_version}"
+  machine_type = "${var.machine_type}"
+
+  # These together will construct the master_user privileges, i.e.
+  # 'master_user_name'@'master_user_host' IDENTIFIED BY 'master_user_password'.
+  # These should typically be set as the environment variable TF_VAR_master_user_password, etc.
+  # so you don't check these into source control."
+  master_user_password = "${var.master_user_password}"
+
+  master_user_name = "${var.master_user_name}"
+  master_user_host = "%"
+
+  # Pass the private network link to the module
+  private_network = "${google_compute_network.private_network.self_link}"
+
+  # Wait for the vpc connection to complete
+  wait_for = "${google_service_networking_connection.private_vpc_connection.network}"
+
+  # Set auto-increment flags to test the
+  # feature during automated testing
+  database_flags = [
+    {
+      name  = "auto_increment_increment"
+      value = "6"
+    },
+    {
+      name  = "auto_increment_offset"
+      value = "6"
+    },
+  ]
+
+  custom_labels = {
+    project = "mysql-private-ip-example"
+  }
+}

examples/mysql-private-ip/outputs.tf

@@ -0,0 +1,33 @@
+output "instance_name" {
+  description = "The name of the database instance"
+  value       = "${module.mysql.instance_name}"
+}
+
+output "ip_addresses" {
+  description = "All IP addresses of the instance as list of maps, see https://www.terraform.io/docs/providers/google/r/sql_database_instance.html#ip_address-0-ip_address"
+  value       = "${module.mysql.ip_addresses}"
+}
+
+output "private_ip" {
+  description = "The first IPv4 address of the addresses assigned to the instance. As this instance has only private IP, it is the private IP address."
+  value       = "${module.mysql.first_ip_address}"
+}
+
+output "instance" {
+  description = "Self link to the master instance"
+  value       = "${module.mysql.instance}"
+}
+
+output "db_name" {
+  description = "Name of the default database"
+  value       = "${module.mysql.db_name}"
+}
+
+output "proxy_connection" {
+  value = "${module.mysql.proxy_connection}"
+}
+
+output "db" {
+  description = "Self link to the default database"
+  value       = "${module.mysql.db}"
+}

examples/mysql-private-ip/variables.tf

@@ -0,0 +1,49 @@
+# ---------------------------------------------------------------------------------------------------------------------
+# REQUIRED PARAMETERS
+# These variables are expected to be passed in by the operator
+# ---------------------------------------------------------------------------------------------------------------------
+
+variable "project" {
+  description = "The project ID to host the database in."
+}
+
+variable "region" {
+  description = "The region to host the database in."
+}
+
+# Note, after a name db instance is used, it cannot be reused for up to one week.
+variable "name_prefix" {
+  description = "The name prefix for the database instance. Will be appended with a random string. Use lowercase letters, numbers, and hyphens. Start with a letter."
+}
+
+variable "master_user_name" {
+  description = "The username part for the default user credentials, i.e. 'master_user_name'@'master_user_host' IDENTIFIED BY 'master_user_password'. This should typically be set as the environment variable TF_VAR_master_user_name so you don't check it into source control."
+}
+
+variable "master_user_password" {
+  description = "The password part for the default user credentials, i.e. 'master_user_name'@'master_user_host' IDENTIFIED BY 'master_user_password'. This should typically be set as the environment variable TF_VAR_master_user_password so you don't check it into source control."
+}
+
+# ---------------------------------------------------------------------------------------------------------------------
+# OPTIONAL PARAMETERS
+# Generally, these values won't need to be changed.
+# ---------------------------------------------------------------------------------------------------------------------
+variable "mysql_version" {
+  description = "The engine version of the database, e.g. `MYSQL_5_6` or `MYSQL_5_7`. See https://cloud.google.com/sql/docs/features for supported versions."
+  default     = "MYSQL_5_7"
+}
+
+variable "machine_type" {
+  description = "The machine type to use, see https://cloud.google.com/sql/pricing for more details"
+  default     = "db-f1-micro"
+}
+
+variable "db_name" {
+  description = "Name for the db"
+  default     = "default"
+}
+
+variable "name_override" {
+  description = "You may optionally override the name_prefix + random string by specifying an override"
+  default     = ""
+}